使用ppt自带vba批量生成pdf

上课老师发的ppt打开太慢，而且文字经常出现乱码，遂想批量转换为pdf

PPT批量转换pdf

（用的VBA）

使用方法：

1.打开ppt页面

​

2. 按Alt+F11进入VBA宏编辑
3. 点击插入模块

2. 把下面的代码复制进去

Sub ConvertPPTsToPDFs()
    Dim xFolder As String
    Dim xFileName As String
    Dim pptApp As Object
    Dim pptPresentation As Object
    Dim xNewName As String
    Dim xIndex As Integer

    ' 直接指定文件夹路径
    xFolder = "D:\库\singal and system\ppt\"
    
    ' 创建PowerPoint应用程序对象
    Set pptApp = CreateObject("PowerPoint.Application")
    pptApp.Visible = True

    ' 获取文件夹中的第一个文件
    xFileName = Dir(xFolder & "*.*", vbNormal)
    While xFileName <> ""
        ' 检查文件是否为PowerPoint文件
        If (Right(xFileName, 4) = ".ppt" Or Right(xFileName, 5) = ".pptx") Then
            ' 打开PowerPoint文件
            Set pptPresentation = pptApp.Presentations.Open(xFolder & xFileName)
            
            ' 获取文件扩展名的位置
            xIndex = InStrRev(xFileName, ".")
            ' 创建新的文件名
            xNewName = Left(xFileName, xIndex - 1) & ".pdf"
            
            ' 导出为PDF
            pptPresentation.SaveAs xFolder & xNewName, 32 ' 32表示PDF格式
            
            ' 关闭演示文稿
            pptPresentation.Close
        End If
        ' 获取下一个文件
        xFileName = Dir()
    Wend
    
    ' 关闭PowerPoint应用程序
    pptApp.Quit
    Set pptApp = Nothing

    MsgBox "所有PowerPoint文件已转换为PDF格式。"
End Sub

​

6.然后把文件目录，也就是最上面这一行“D:\库\数字信号处理”替换掉

换成自己存放ppt的文件夹的地址

例如：C:\Users\ak12s\Pictures\Screenshots

注意不要把引号删掉哦(⊙o⊙)？

​

​

替换后

7.点击运行：

​